qemu.bat

@echo off
set ROOT_DIR=%~dp0

set QEMU_TOOLS=qemu-system-arm.exe
set FILE=rtthread-imx6.elf
set RUN_TYPE=%1

rem parameter setting
set MACHINES=mcimx6ul-evk  -smp cpus=1
set NO_DISPLAY=-nographic
set DISPLAY=-display sdl -show-cursor
set SERIAL_PORT=mon:stdio
set NETWORK=-nic user

if exist %FILE% goto run
call scons -j4

:run

if "%RUN_TYPE%"=="" (
    goto _help
) else (
    goto _start
)

:_help
set var=""
echo "help(%0 [gui|nogui|debug]):"
echo "  1. gui"
echo "  2. nogui"
echo "  3. debug"
set /p var=Please input manually: 
if "%var%"=="1" (
    goto gui_start
) else if "%var%"=="2" (
    goto nogui_start
) else if "%var%"=="3" (
    goto debug_start
) else (
    echo "Input error!"
    goto _help
)

:_start
if "%RUN_TYPE%"=="gui" (
    goto gui_start
) else if "%RUN_TYPE%"=="nogui" (
    goto nogui_start
) else if "%RUN_TYPE%"=="debug" (
    goto debug_start
) else (
    goto _help
)

:gui_start
%QEMU_TOOLS% -M %MACHINES% -kernel %FILE% %DISPLAY% -serial %SERIAL_PORT% %NETWORK%
goto end

:nogui_start
%QEMU_TOOLS% -M %MACHINES% -kernel %FILE% %NO_DISPLAY% -serial %SERIAL_PORT% %NETWORK%
goto end

:debug_start
%QEMU_TOOLS% -M %MACHINES% -m 512M -kernel %FILE% %NO_DISPLAY% -serial %SERIAL_PORT% %NETWORK% -S -s
goto end

:end
pause